MediaControlAPI
Contents
Description
The MediaControl API is a generic Media player API. The idea is to define a generic video-player API, that could be reused with other players. It is implemented in VLC by using the New libvlc API, and both APIs can cooperate (i.e. you can instanciate a MediaControl object from an existing libvlc instance, and vice-versa).
Its core part (playback control) has been taken from the OMG Audio/Video Stream specification, and extended with additional functionalities. An IDL specification MediaControl.idl has been the base of this work.
FIXME : The API is defined in "include/vlc/mediacontrol.h" and implemented in "src/control".
The Doxygen documentation can be found at [1].
Current status
The API currently includes functions for the following things:
- Playback
- Basic features (play/pause/stop)
- Seeking
- Basic playlist interaction
- Stream information
- Audio/Video
- Snapshot control (on the fly only)
- OSD display (of text and SVG graphics through the svg rendering module)
- Volume setting
- Setting the visual ID of an embedding window
Current uses
The MediaControl API is used by the following modules :
- the PythonBinding
- the JavaBinding
Foreseen evolutions
The following evolutions should be integrated in the API, but discussion is necessary to ensure that they are sufficiently flexible to match various needs :
- sound_[sg]et_volume: normalize volume in [0..100]
- implement get_api_version() or get_capabilities() (which would return the list of capabilities supported by the player: ("core", "svg", "snapshot", etc)
- Complete the implementation. For instance, the frame-by-frame unit (mediacontrol_SampleCount) is not implemented, and the stop/pause do not take the Position parameter into account (they are applied immediately).
- Fix VLC initialization on Win32 so that it uses the registry key to find the default plugins directory by default. Currently, it uses the vlc.exe path, which it cannot find when using VLC embedded. A workaround is to chdir to the vlc.exe directory before instanciating the MediaControl() object.
Current API
Here is an IDL description of the current version of MediaControlAPI. In case of doubt, refer to the mediacontrol.h file.
/*
Module inspired by the MediaControl IDL
*/
module VLC {
const float VERSION = 0.1;
enum PositionOrigin {
AbsolutePosition, RelativePosition, ModuloPosition
};
enum PositionKey {
ByteCount, SampleCount, MediaTime
};
struct Position {
PositionOrigin origin;
PositionKey key;
long long value;
};
exception PositionKeyNotSupported { string message; };
exception PositionOriginNotSupported { string message; };
exception InvalidPosition { string message; };
exception PlaylistException { string message; };
exception InternalException { string message; };
typedef sequence<string> PlaylistSeq;
typedef sequence<octet> ByteSeq;
struct RGBPicture {
short width;
short height;
long type;
ByteSeq data;
long long date;
};
typedef sequence<RGBPicture> RGBPictureSeq;
/* Cf stream_control.h */
enum PlayerStatus { PlayingStatus, PauseStatus, ForwardStatus, BackwardStatus, InitStatus, EndStatus, UndefinedStatus };
struct StreamInformation {
PlayerStatus streamstatus;
string url; /* The URL of the current media stream */
long mux_rate; /* the rate we read the stream in bytes/s */
long long position; /* actual location in the area (in arbitrary units) */
long long size; /* total size of the area (in arbitrary units) */
};
// MediaControl interface is similar to
// ControlledStream interface in MSS.
// It can be inherited by flow endpoints or
// FlowConnection interfaces.
interface MediaControl
{
Position get_media_position(in PositionOrigin an_origin,
in PositionKey a_key)
raises (InternalException, PositionKeyNotSupported);
void set_media_position(in Position a_position)
raises (InternalException, PositionKeyNotSupported, InvalidPosition);
void start(in Position a_position)
raises (InternalException, InvalidPosition, PlaylistException);
void pause(in Position a_position)
raises (InternalException, InvalidPosition);
void resume(in Position a_position)
raises (InternalException, InvalidPosition);
void stop(in Position a_position)
raises (InternalException, InvalidPosition);
oneway void exit (); // Exits the player (not in the original spec)
void playlist_add_item (in string a_file)
raises (PlaylistException);
void playlist_clear ()
raises (PlaylistException);
// Returns the list of files in playlist
PlaylistSeq playlist_get_list ()
raises (PlaylistException);
// Returns a snapshot of the currently displayed picture
RGBPicture snapshot (in Position a_position)
raises (InternalException);
RGBPictureSeq all_snapshots ()
raises (InternalException);
// Displays the message string, between "begin" and "end" positions
void display_text (in string message, in Position begin, in Position end)
raises (InternalException);
StreamInformation get_stream_information ()
raises (InternalException);
unsigned short sound_get_volume()
raises (InternalException);
void sound_set_volume(in unsigned short volume)
raises (InternalException);
};
};
API evolution
Here is an IDL description of the intended next version of MediaControlAPI. It is not fully implemented yet (esp. the playlist handling).
module VLC {
const float VERSION = 1.0;
enum PositionOrigin {
AbsolutePosition,
RelativePosition,
// Like relative, but wraps at the end of a file for instance:
ModuloPosition
};
enum PositionKey {
// For raw access
ByteCount,
// Frame number
SampleCount,
// In milliseconds
MediaTime
};
struct Position {
PositionOrigin origin;
PositionKey key;
long long value;
};
exception PositionKeyNotSupported { string message; };
exception PositionOriginNotSupported { string message; };
exception InvalidPosition { string message; };
exception PlaylistException { string message; };
exception InternalException { string message; };
typedef sequence<string> PlaylistSeq;
typedef sequence<octet> ByteSeq;
struct RGBPicture {
short width;
short height;
long type;
ByteSeq data;
// Timestamp (absolute position in the movie) in ms
long long date;
};
struct StreamInformation {
short width;
short height;
float aspect_ratio;
long bitrate;
string codec;
string author;
};
typedef sequence<RGBPicture> RGBPictureSeq;
enum PlayerStatus { PlayingStatus, PauseStatus, ForwardStatus, BackwardStatus, InitStatus, EndStatus, UndefinedStatus };
struct StatusInformation {
PlayerStatus streamstatus;
string url; /* The URL of the current media stream */
long long position; /* actual location in the stream (in ms) */
long long length; /* total length of the stream (in ms) */
};
interface Playlist
{
// Return a playlist item id
int add(in string a_file)
raises (PlaylistException);
void next(in string a_file)
raises (PlaylistException);
void prev(in string a_file)
raises (PlaylistException);
// Set the new current item
void set(int item_id)
raises (PlaylistException);
void remove(int item_id)
raises (PlaylistException);
// Clear the whole playlist
void clear ()
raises (PlaylistException);
// Return the list of files in playlist
PlaylistSeq get_list ()
raises (PlaylistException);
}
// MediaControl interface is similar to
// ControlledStream interface in MSS.
// It can be inherited by flow endpoints or
// FlowConnection interfaces.
interface MediaControl
{
// *** Initialization
// Exit the player
oneway void exit ();
// Return the IDL API version
string get_api_version();
// Return the player version (player name + version)
string get_player_version();
// *** Playback control
// The a_position parameters are facultative.
void start(in Position a_position)
raises (InternalException, InvalidPosition, PlaylistException);
void pause(in Position a_position)
raises (InternalException, InvalidPosition);
void resume(in Position a_position)
raises (InternalException, InvalidPosition);
void stop(in Position a_position)
raises (InternalException, InvalidPosition);
Position get_media_position(in PositionOrigin an_origin,
in PositionKey a_key)
raises (InternalException, PositionKeyNotSupported);
void set_media_position(in Position a_position)
raises (InternalException, PositionKeyNotSupported, InvalidPosition);
// Rate control. The rate is a signed value, corresponding to
// the percentage of the speed (+100 = normal, -100 = reverse...)
int get_rate()
raises (InternalException);
void set_rate(int rate)
raises (InternalException);
// *** Media information
StatusInformation get_status_information ()
raises (InternalException);
// Return information about the current stream
StreamInformation get_stream_information ()
raises (InternalException);
// *** Playlist handling
Playlist playlist()
raises (InternalException);
// *** Video
// Return a snapshot of the currently displayed picture
RGBPicture snapshot (in Position a_position)
raises (InternalException);
// Return the whole snapshot cache contents
RGBPictureSeq all_snapshots ()
raises (InternalException);
// Display the message string as caption,
// between "begin" and "end" positions
void render_text (in string message, in Position begin, in Position end)
raises (InternalException);
// Set the visual ID (XID in X-Window, HWIN on Win32, ??? on MacOS
// X) for the player window
void set_visual(long xid)
raises (InternalException);
boolean get_fullscreen()
raises (InternalException);
void set_fullscreen(boolean full)
raises (InternalException);
// *** Audio
// Volume is normalized in [0..100]
unsigned short sound_get_volume()
raises (InternalException);
void sound_set_volume(in unsigned short volume)
raises (InternalException);
void sound_mute()
raises (InternalException);
};
};
